*==========================================================
* MC33262
* ON Semiconductor
* Power Factor Controllers
*
* This model was developed for ON Semiconductor by:
* AEI Systems, LLC
* 5777 W. Century Blvd. Suite 876
* Los Angeles, California 90045
* Copyright 2002, all rights reserved.
*
* This model is subject to change without notice.
* Users may not directly or indirectly re-sell or 
* re-distribute this model. This model may not 
* be used, modified, or altered 
* without the consent of ON Semiconductor. 
*
* For more information regarding modeling services,
* model libraries and simulation products, please
* call AEi Systems at (310) 863-8034, or contact 
* AEi by email: info@aeng.com. http://www.AENG.com
*
* Revision: 1.0 
*==========================================================
*
* PSpice translation by Christophe Basso, christophe.basso@onsemi.com
*
.SUBCKT MC33262 1 2 3 4 5 6 7 8
*POWER FACTOR CONTROLLER
*Terminal Identifications are
*Voltage fedback Input=1 Compensation=2
*Multiplier Input=3 Current sense Input=4
*Zero Current Detect Input=5 GND=0 Drive Output=7 Vcc=8
RdumGND 6 0 1u
XTOF2 0 42 49 0 SWhyste PARAMS: VT=1.5 VH=0.1 RON=1 ROFF=1MEG
XTOF1 9 11 8 0 SWhyste PARAMS: VT=10.5 VH=2.5 RON=1 ROFF=1MEG
V1 9 0 2.5
R1 11 0 100K
E1 10 0 12 13 1
Q1 8 14 12 Q33262
Q2 15 16 0 Q33262
V3 10 17 
R2 13 14 200
R3 17 16 1
GB1 12 13 Value = { 0.55M*V(18)*V(8)+I(V3) }
R4 12 7 10
R5 15 7 10
C1 12 0 50P
V4 19 0 16
D1 14 19 D33262A
EB2 18 0 Value = { IF ( V(50)<1 & V(11)>1, 2, -2 ) }
GB3 2 0 Value = { 20U/(1+EXP(V(26))) }
X1 21 22 LIM33262 params: K=1 PLIM=100 NLIM=100
E2 21 0 9 1 20
V5 24 0 6.4
D2 2 24 D33262
I1 0 2 10U
D3 25 20 D33262
D4 25 2 D33262
C2 26 0 100P
R6 0 26 2.901K
L1 22 26 3.161M
X2 23 30 LIM33262 params: K=10 PLIM=16 NLIM=16
V7 3 23 1.6
EB4 32 0 Value = { V(30)/10+1.6 }
X3 27 31 LIM33262 params: K=10 PLIM=8.75 NLIM=8.75
V8 2 27 2.875
EB5 28 0 Value = { V(31)/10+2.875 }
EB6 29 0 Value = { 544M*(V(28)-1.98)*V(32)+41.7M*(V(28)-1.98) }
X4 29 38 LIM33262 params: K=1 PLIM=1.55 NLIM=1.55
C3 34 0 10P IC=0
R9 4 34 20K
EB7 36 0 Value = { IF ( V(34)>V(33), 0, 2 ) }
R10 37 45 40K
C4 45 0 10P
VOFFSET 33 38 9M
EB8 35 0 Value = { IF ( V(45)>2.7, 0, 2 ) }
V9 39 46 32.5
D5 8 39 D33262A
V10 40 0 1.2
D6 5 43 D33262A
V11 43 0 6
R13 42 9 100K
E3 37 0 1 0 1
E4 57 0 5 0 1
R14 57 49 32K
C5 49 0 10P IC=0
X5 47 48 50 51 RS33262 params: TD=1N
EB9 47 0 Value = { IF ( V(44)>1 & V(59)>1, 2, 0 ) }
EB10 48 0 Value = { IF ( V(47)>1 & V(54)>1, 0, IF ( V(52)>1.667, 0, 2 ) ) }
D7 52 9 D33262A
GB11 52 0 Value = { IF ( V(44)>1 & V(42)>1 & V(50)>1 & V(11)>1, -10U, 2M ) }
D8 0 52 D33262A
C6 52 0 2.8N IC=-0.673
V13 53 0 PULSE 0 2
GB13 8 0 Value = { IF ( V(11)<1, V(8)/28K, 81.6U*V(8)+7.847M ) }
R17 46 0 454
D9 40 5 D33262A
X6 44 54 60 59 RS33262  params: TD=1N
EB14 44 0 Value = { IF ( V(53) > 1 & V(35)>1 & V(36)>1, 2, 0 ) }
EB16 54 0 Value = { IF ( V(44) < 1, 2, IF ( V(52)>1.667, 0, V(42) ) ) }
V14 20 0 1.7
I4 0 25 680U
*** discrete models ***
.MODEL D33262A D CJO=2P
.MODEL D33262 D CJO=2P N=0.5
.MODEL Q33262 NPN (IS=15.2F NF=1 BF=105 VAF=98.5 IKF=.5
+ ISE=8.2P NE=2 BR=4 NR=1 VAR=20 IKR=.225 RE=.373 RB=1.49
+ RC=.149 XTB=1.5 CJE=35.5P CJC=12.2P TF=0.5N TR=10N)
.ENDS
********** Model subckts *********
.SUBCKT LIM33262 1 2 params: k=1 nlim=16 plim=16
RIN 1 0 1E12
E1 3 0 VALUE = { V(0,1)* K}
RC1 2 4 1MEG
C1 2 4 1F IC=0
R1 3 4 1MEG
E2 2 0 0 4 1E6
VN 5 2 {NLIM-.0597}
DN 4 5 DN
*
.MODEL DN D(IS=1E-12 N=.14319)
VP 2 6 {PLIM-.0597}
DP 6 4 DN
.ENDS
*
.SUBCKT RS33262 2 3 4 5 params: TD=1N
*RS LATCH FLIP FLOP TERMINAL ID#
*SET=2 RESET=3 Q=4 QB=5
C1 11 0 10P
R3 10 8 {TD/6.9315P}
C3 8 0 10P
EB1 10 0 Value = { IF ( V(2)>1 & V(5)>1, 0, 2 ) }
EB2 16 0 Value = { IF ( V(3)>1 & V(4)>1, 0, 2 ) }
EB5 4 0 Value = { IF ( V(8)>1, 2, 0 ) }
EB6 5 0 Value = { IF ( V(11)>1, 2, 0 ) }
R1 16 11 {TD/6.9315P}
.ENDS
*****
* PSpice hysteresis switch made by Chris Basso
.subckt SWhyste NodeMinus NodePlus Plus Minus PARAMS: RON=1 ROFF=1MEG VT=5 VH=2
S5 NodePlus NodeMinus 8 0 smoothSW
EBcrtl 8 0 Value = { IF ( V(plus)-V(minus) > V(ref), 1, 0 ) }
EBref ref1 0 Value = { IF ( V(8) > 0.5, {VT-VH}, {VT+VH} ) }
Rdel ref1 ref 100
Cdel ref 0 100p  IC={VT+VH}
Rconv1 8 0 10Meg
Rconv2 plus 0 10Meg
Rconv3 minus 0 10Meg
.model smoothSW VSWITCH (RON={RON} ROFF={ROFF} VON=1 VOFF=0)
.ends SWhyste
**** Application related models ****
.SUBCKT MTP8N50  10 20 40
*     TERMINALS:  D  G  S
* Mot 500 Volt  8 Amp  .8 ohm  N-Channel Power MOSFET  02-17-1993
M1   1  2  3  3  DMOS L=1U W=1U
RD  100  1  .379
RS  30  3  21M
RG  20  2  18.7
CGS  2  3  1.45N
EGD 12  0  2  1  1
VFB 14  0  0
FFB  2  1  VFB  1
CGD 13 14  1.52N
R1  13  0  1
D1  12 13  DLIM
DDG 15 14  DCGD
R2  12 15  1
D2  15  0  DLIM
DSD  3 10  DSUB
LD 100 10  4N
LS  30 40  7.5N
.MODEL DMOS NMOS (LEVEL=3 THETA=60M VMAX=1.04MEG ETA=2M VTO=3.2 KP=3.46)
.MODEL DCGD D (CJO=1.52N VJ=.6 M=.68)
.MODEL DSUB D (IS=33.2N N=1.5 RS=43.7M BV=500 CJO=860P VJ=.8 M=.42 TT=600N)
.MODEL DLIM D (IS=100U)
.ENDS
*********
**** SINGLE WINDING TRANSFORMER ****
.SUBCKT XFMR1 1 2 3 4 PARAMS: RATIO=1
RP 1 2 1MEG
E 5 4 VALUE = { V(1,2)*RATIO }
G 1 2 VALUE = { I(VM)*RATIO }
RS 6 3 1U
VM 5 6 
.ENDS XFMR1
*******
.MODEL MUR130 D BV=400 CJO=15.7P IBV=5U IS=1.08U M=.310
+ N=2.59 RS=55.5M TT=108N VJ=.75
.MODEL DN4934 D BV=1.33E+02 CJO=2.39E-11 IBV=1.00E-06
+ IS=2.06E-08 M=.41 N=2.00 RS=2.26E-02 TT=2.16E-07 VJ=.75
.MODEL DN4722 D BV=533 CJO=124P IBV=.5M IS=462P M=.333
+ N=1.42 RS=11.5M TT=21.6U VJ=.75
********